Книга: Обработка баз данных на Visual Basic®.NET

Применение технологии XPATH

Применение технологии XPATH

Что происходит после загрузки XML-документа? В пространстве имен System.xml предусмотрены классы xmlNode и xmlNodeList. С помощью этих классов и технологии XPATH происходит считывание XML-документа и извлечение интересующих нас данных. В листинге 9.5 показано простое приложение Visual Basic .NET, которое загружает XML-документ из файла simple2.xsl и выводит все имена (атрибут FirstName) в текстовом поле.

Imports System.Xml
Imports System.Xml.XPath
Imports System.IO
Public Class Form1
 Inherits System.Windows.Forms.Form
…
' Здесь опущен код, сгенерированный Windows Form Designer.
…
 Private Sub Form1_Load(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles MyBase.Load
  Dim xDoc As New XmlDocument()
  xDoc.Load("simple2.xml")
  ' Обратите внимание, что для получения значения
  ' атрибута используется синтаксис XPATH.
  Dim xNodeList As XmlNodeList = _
   xDoc.SelectNodes("descendant::tblCustomer/@FirstName")
  Dim xNode As XmlNode
  Dim i As Integer = 0
  For Each xNode In xNodeList
   lstResults.Items.Insert(i, xNode.InnerText)
   i = i + 1 Next
  End Sub
End Class

Для выполнения этого кода создайте новый проект, форму, а в форме — поле со списком lstResults. Поместите код подпрограммы Form1_Load из листинга 9.5 в код формы. После компоновки и запуска приложения в поле со списком будут показаны результаты, показанные на рис. 9.2 (при условии, что в каталоге выполняемого файла находится файл simple2.xml).  

РИС. 9.2. Результаты выполнения кода из листинга 9.5

Как видите, загрузка XML-документа и циклический обход его данных не представляют собой большой проблемы. А как можно изменить данные в XML-документе? Ответ на это вопрос основан на комбинации использованных ранее классов.

В листинге 9.6 приведен измененный код данного примера, в котором можно изменять и сохранять значение каждого узла в XML-документе. В этом достаточно простом примере используются чрезвычайно эффективные и надежные средства изменения XML-документа. Помимо упомянутых выше изменений, в данное приложение также включены кнопки btnShowTop10 и btnChangeAndSave для вызова отдельных подпрограмм отображения и изменения данных. После создания новых кнопок, компоновки проекта и запуска приложения щелкните на кнопке ShowTop10. После выполнения этих действий в поле со списком будут представлены результаты, показанные на рис. 9.2. (Учтите: это возможно лишь при условии, что в каталоге выполняемого файла находится файл simple2.xml.) Для редактирования одного из значений щелкните дважды на том элементе списка, который нужно изменить. Затем в диалоговом окне ChangeAndSave введите новое имя и щелкните на кнопке OK. После этого в поле со списком будет отображено обновленное состояние XML-документа с измененными значениями списка.

Imports System.Xml
Imports System.Xml.XPath
Imports System.IO
Public Class Form1
 Inherits System.Windows.Forms.Form
 …
 ' Здесь опущен код, сгенерированный Windows Form Designer.
 …
 Private Sub Form1_Load(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles MyBase.Load
 End Sub
Private Sub ShowTop10()
  Dim xDoc As New XmlDocument()
  xDoc.Load("simple2.xml")
  ' Обратите внимание, что для получения значения атрибута
  ' используется синтаксис XPATH.
  Dim xNodeList As XmlNodeList = _
   xDoc.SelectNodes("descendant::tblCustomer/@FirstName")
  Dim xNode As XmlNode
  Dim i As Integer = 0
  For Each xNode In xNodeList
   lstResults.Items.Insert(i, xNode.InnerText)
   i = i + 1
  Next
 End Sub
 Public Sub ChangeNameandSave(ByVal NameToChange As String, ByVal ChangeTo _
  As String)
  Dim xDoc As New XmlDocument()
  xDoc.Load("simple2.xml")
  Dim xNodeList As XmlNodeList = _
   xDoc.SelectNodes("descendant::tblCustomer/@FirstName")
  Dim xNode As XmlNode
  For Each xNode In xNodeList
   If xNode.InnerText = NameToChange Then
    xNode.Value = ChangeTo
   End If
  Next
  xDoc.Save("simple2.xml")
  MsgBox("Name change saved!", 0)
  lstResults.Items.Clear()
  ShowTop10()
 End Sub
 Private Sub btnShowTop10_Click(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles btnShowTop10.Click
  ShowTop10()
 End Sub
 Private Sub lstResults_DoubleClick(ByVal sender As Object, _
  ByVal e As System.EventArgs) Handles lstResults.Doubleclick
  Dim oldName As String = _
   lstResults.GetItemText(lstResults.Items.Item(lstResults.SelectedIndex))
  Dim newName As String = _
   InputBox("Please enter a new name", "ChangeAndSave")
  ChangeNameandSave(oldName, newName)
 End Sub
End Class

Оглавление книги