Книга: Обработка баз данных на Visual Basic®.NET

Передача данных из источника данных в объект DataSet

Передача данных из источника данных в объект DataSet

Для использования объекта DataAdapter требуется, как минимум, подключение к базе данных и команда Select. Для этого можно использовать объекты Connection и Command, т.е. создать их, конфигурировать и присвоить их свойствам Connection и SelectCommand объекта DataAdapter. Однако гораздо удобнее использовать для этого конструктор объекта DataAdapter с двумя строковыми параметрами: один для команды SELECT, а второй для строки подключения, как показано ниже.

Dim da As SqlDataAdapter = New SqlDataAdapter( _
  "select * from tblDepartment" _
  "server=localhost;uid=sa;database=Novelty")

Попробуем теперь вызвать метод Fill для извлечения данных из базы данных Novelty и загрузки их в объект DataSet. Для этого вернитесь к проекту DataSetCode из главы 5, "ADO.NET: объект DataSet", и выполните перечисленные ниже действия.

1. Щелкните правой кнопкой мыши на проекте DataSetCode в окне Solution Explorer и выберите в контекстном меню команду Properties, чтобы открыть диалоговое окно DataSetCode Property Pages.

2. Выберите раздел General в папке Common Properties в правой части диалогового окна DataSetCode Property Pages, а затем выберите форму frmDataSets в поле Startup object.

3. Откройте форму frmDataSets в окне конструктора формы. 

4. Создайте новую кнопку непосредственно под кнопкой Constraints, перетаскивая ее из панели элементов управления.

5. В окне свойств Properties укажите значение btnDataAdapterFill для свойства (Name) и значение DataAdapter Fill для свойства Text.

6. Для использования провайдера данных SqlClient нужно импортировать его пространство имен с помощью команды, отмеченной полужирным начертанием в следующем фрагменте кода:

Imports System
Imports System.Data
Imports System.Data.SqlClient

7. Вставьте код, показанный в листинге 6.1.

Private Sub btnDataAdapterFill_Click(ByVal sender As _
 System.Object, ByVal e As System.EventArgs) _
 Handles btnDataAdapterFill.Click
 ReadData()
End Sub
Private Sub ReadData()
 Dim rows As Integer
 Dim daDepartments As SqlDataAdapter = New SqlDataAdapter( _
  "select * from tblDepartment", _
  "server=localhost;uid=sa;database=novelty")
 dsEmployeeInfo = New DataSet()
 rows = daDepartments.Fill(dsEmployeeInfo, "Departments")
 DisplayDataSet(dsEmployeeInfo)
End Sub

После создания объекта daDepartments с двумя аргументами, которые содержат команду Select и строку подключения, вызывается метод Fill для наполнения данными таблицы Departments набора данных dsEmployeeInfo. Метод Fill также возвращает количество записей, которые включены (или обновлены) в набор данных dsEmployeeInfo. При выполнении метода Fill провайдером данных неявно выполняются перечисленные ниже действия.

• Для объекта SelectCommand открывается подключение к источнику данных, если оно еще не открыто.

• Выполняется команда, указанная в свойстве CommandText объекта SelectCommand (вместе с параметрами, если таковые имеются).

• Создается объект DataReader для возвращения имен полей и типов, использованных для создания нового объекта DataTable в указанном наборе данных DataSet, если этого объекта еще не существует.

• Объект DataReader используется для извлечения данных и вставки их в таблицу.

• Объект DataReader закрывается.

• Подключение к источнику данных закрывается, если оно было открыто объектом DataReader, в противном случае оно остается открытым.

Методу Fill передается ссылка на набор данных dsEmployeeInfo и имя таблицы Departments, в которую вставляются данные. Вместо имени таблицы можно было бы передать ссылку на объект DataTable. Еще один вариант указания параметров основан на передаче только ссылки на объект DataSet, а метод Fill в таком случае по умолчанию загрузит данные в объект DataTable по имени Table.

Для загрузки данных во вторую таблицу можно создать второй объект DataAdapter с другой командой Select. В данном примере для загрузки данных в таблицы Department и Employees из соответствующих таблиц базы данных нужно использовать приведенный ниже код для подпрограммы ReadData() вместо кода из листинга 6.1.

Private Sub ReadData()
 Dim rows As Integer
 Dim daDepartments As SqlDataAdapter = New SqlDataAdapter(_
  "select * from tblDepartment", _
  "server=localhost;uid=sa;database=novelty")
 Dim daEmployees As SqlDataAdapter = New SqlDataAdapter(_
  "select * from tblEmployee", _
  "server=localhost;uid=sa;database=novelty")
 dsEmployeeInfo = New DataSet()
 rows = daDepartments.Fill(dsEmployeeInfo, "Departments")
 rows = daEmployees.Fill(dsEmployeeInfo, "Employees")
 DisplayDataSet(dsEmployeeInfo)
End Sub

Скомпонуйте проект DataSetCode, щелкните на кнопке DataAdapter Fill, и в поле со списком, как и прежде, будет отображена информация о содержании набора данных dsEmployeeInfo, но теперь она извлекается из базы данных под управлением SQL Server, а не генерируется локально кодом приложения.

Для установления родительско-дочерних связей между записями в этих таблицах можно создать объект DataRelation, который служит отношением между ними.

Совсем необязательно использовать разные объекты DataAdapter для таблиц одного набора данных. Иногда для них можно использовать один объект DataAdapter, только изменяя параметр с текстом команды SQL. Этот способ прекрасно подходит для многочисленных вызовов метода Fill, так как программирование всех отдельных операций создания и изменения команд обновления (вставки, обновления и удаления) каждого объекта DataTable в соответствии с изменениями источника данных требует много времени и усилий.

Итак, для использования одного объекта DataAdapter предыдущий код следует заменить приведенным ниже.

Private Sub ReadData()
 Dim rows As Integer
 Dim da As SqlDataAdapter = New SqlDataAdapter( _
  "select * from tblEmployee", _
  "server=localhost;uid=sa;database=novelty")
 dsEmployeeInfo = New DataSet()
 rows = da.Fill(dsEmployeeInfo, "Employees")
 ' Изменение текста команды SQL.
 da.SelectCommand.CommandText = _
  "select * from tblDepartment"
 rows = da.Fill(dsEmployeeInfo, "Departments")
 DisplayDataSet(dsEmployeeInfo)
End Sub

В листинге 6.2 демонстрируется еще один способ использования одного объекта DataAdapter для выполнения нескольких операций вставки данных в один объект DataTable.

Private Sub ReadData()
 Dim daEmployees As SqlDataAdapter = New SqlDataAdapter(_
  "select * from tblEmployee where DepartmentID = 1", _
  "server=localhost;uid=sa;database=novelty")
 dsEmployeeInfo = New DataSet()
 daEmployees.Fill(dsEmployeeInfo, "Employees")
 ' Изменение текста команды SQL.
 daEmployees.SelectCommand.CommandText = _
  "select * from tblEmployee where DepartmentID = 3"
 daEmployees.Fill(dsEmployeeInfo, "Employees")
 DisplayDataSet(dsEmployeeInfo)
End Sub

Обратите внимание, что в листинге 6.2 возвращаемое значение метода Fill уже не сохраняется в локальной переменной rows. Совсем необязательно сохранять возвращаемое значение, если только в дальнейшем не предполагается проверять его или использовать каким-то другим способом. Предлагаемый в листинге 6.2 код можно было бы расширить несколькими командами Select для обновления объекта DataTable наиболее свежими данными (например, измененными другими пользователями) из источника данных.

Оглавление книги