Книга: Технология XSLT

Функция translate

Функция translate

string translate(string, string, string)

Функция translate производит замену символов первого своего строкового аргумента, которые присутствуют во втором аргументе на соответствующие символы третьего аргумента.

Пример

translate('abcdefgh', 'aceg', 'ACEG') ? 'AbCdEfGh'

Если некоторый символ повторяется во втором аргументе несколько раз, учитывается только первое его появление.

Пример

translate('abcdefgh', 'acaeaga', 'ACBECGD') ? 'AbCdEfGh'

Если второй аргумент длиннее третьего, символы, для которых нет соответствующей замены, удаляются из строки.

Пример

translate('a b-c=d+e|f/gh', 'aceg-=+|/', 'ACEG') ? 'AbCdEfGh'

Если третий аргумент длиннее второго, остаток строки игнорируется.

Пример

translate('abcdefgh', 'aceg', 'ACEGBDFH') ? ' AbCdEfGh'

Функцию translate можно использовать, например, для изменения регистра символов. Конечно, это будет работать только для тех языков, для которых такая функция будет записана, но и этого в большинстве случаев будет достаточно. В будущем предполагается включить в новые версии языка более мощные функции для работы с регистрами символов.

Пример

Для того чтобы изменять регистр слов русского языка, мы можем определить две переменные, lowercase и uppercase, которые будут содержать строчные и прописные символы основного русского алфавита (мы включили в него букву ё — строчную ("ё") и прописную ("Ё"), хотя в соответствии с Unicode она относится к расширениям). Мы также создадим два именованных шаблона, которые будут менять регистр символов строкового параметра str. Для удобства использования мы вынесем определения переменных и шаблонов во внешний модуль ru.xsl.

Листинг 6.6. Преобразование ru.xsl

<xsl:stylesheet
 version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:variable
  name="uppercase"
  select="concat('&#x410;&#x411;&#x412;&#x413;',
                 '&#x414;&#x415;&#x401;&#x416;&#x417;',
                 '&#x418;&#x419;&#x41A;&#x41B;',
                 '&#x41C;&#x41D;&#x41E;&#x41F;',
                 '&#x420;&#x421;&#x422;&#x423;',
                 '&#x424;&#x425;&#x426;&#x427;',
                 '&#x428;&#x429;&#x42A;&#x42B;',
                 '&#x42C;&#x42D;&#x42E;&#x42F;')"/>
 <xsl:variable
  name="lowercase"
  select="concat('&#x430;&#x431;&#x432;&#x433;',
                 '&#x434;&#x435;&#x451;&#x436;&#x417;',
                 '&#x438;&#x439;&#x43A;&#x43B;',
                 '&#x43C;&#x43D;&#x43E;&#x43F;',
                 '&#x440;&#x441;&#x442;&#x443;',
                 '&#x444;&#x445;&#x446;&#x447;',
                 '&#x448;&#x449;&#x44A;&#x44B;',
                 '&#x44C;&#x44D;&#x44E;&#x44F;')"/>
 <xsl:template name="lower">
  <xsl:param name="str"/>
  <xsl:value-of select="translate($str, $uppercase, $lowercase)"/>
 </xsl:template>
 <xsl:template name="upper">
  <xsl:param name="str"/>
  <xsl:value-of select="translate($str, $lowercase, $uppercase)"/>
 </xsl:template>
</xsl:stylesheet>

Использовать этот модуль можно, включив или импортировав его в основное преобразование элементами xsl:include или xsl:import. После этого в основном преобразовании будут доступны переменные lowercase и uppercase, которые можно будет использовать в функции translate и шаблоны с именами lower и upper.

Использовать функцию translate с переменными lowercase и uppercase можно следующим образом:

translate('Дом', $uppercase, $lowercase) ? 'дом'
translate('Дом', $lowercase, $uppercase)
? 'ДОМ'

Именованные шаблоны можно вызывать элементом xsl:call-template, передавая параметр при помощи xsl:with-param. Например, следующий фрагмент шаблона

...
<xsl:call-template name="lower">
 <xsl:with-param name="str" select="'Дом'"/>
</xsl:call-template
>

...

создаст в выходящем дереве текстовый узел со значением "дом".

Оглавление книги


Генерация: 0.777. Запросов К БД/Cache: 3 / 0
поделиться
Вверх Вниз