Книга: Программирование мобильных устройств на платформе .NET Compact Framework

Листинг 13.6. Код формы, демонстрирующий загрузку встроенных ресурсов

'-----------------------------------------------------------
'Загрузить изображение и отобразить его в объекте PictureBox
'-----------------------------------------------------------
Private Sub Button1_Click(ByVal sender As System.Object, _
 ByVal e As System.EventArgs) Handles Button1.Click
 LoadImageFromResource()
 PictureBox1.Image = m_myBitmapImage
End Sub
Private m_myBitmapImage As System.Drawing.Bitmap
'------------------------------------------------------------------
'Загрузить изображение, которое хранится в виде встроенного ресурса
'в нашей сборке
'------------------------------------------------------------------
Public Sub LoadImageFromResource()
 'Если изображение уже загружено,
 'то не имеет смысла делать это повторно.
 If Not (m_myBitmapImage Is Nothing) Then
  Return
 End If
 '----------------------------------------------------
 'Получить ссылку на двоичную сборку нашего приложения
 '----------------------------------------------------
 Dim thisAssembly As System.Reflection.Assembly = _
  System.Reflection.Assembly.GetExecutingAssembly()
 '-------------------
 'Получить имя сборки
 '-------------------
 Dim thisAssemblyName As System.Reflection.AssemblyName = _
  thisAssembly.GetName()
 Dim assemblyName As String = thisAssemblyName.Name
 '-----------------------------------------------------------------------
 'Извлечь поток изображения из нашей сборки и создать соответствующую ему
 'битовую карту в памяти
 'ПРИМЕЧАНИЕ: Имя потока ресурса ResourceStream ЧУВСТВИТЕЛЬНО К РЕГИСТРУ,
 '   поэтому имя изображения должно В ТОЧНОСТИ совпадать с именем
 '   файла изображения, который вы добавили в проект
 '-----------------------------------------------------------------------
 m_myBitmapImage = New System.Drawing.Bitmap( _
  thisAssembly.GetManifestResourceStream( _
  assemblyName + ".MyImage.PNG"))
End Sub

Оглавление книги