Книга: Программируем Arduino. Профессиональная работа со скетчами.

5. Снижение потребления электроэнергии

5. Снижение потребления электроэнергии

Справедливости ради следует отметить, что и без применения специальных мер платы Arduino потребляют не особенно много электроэнергии. Обычно Arduino Uno потребляет ток около 40 мА, что при питании через разъем USB с напряжением 5 В составляет всего 200 мВт. Это означает, что она может благополучно работать около четырех часов, питаясь от аккумулятора 9 В (емкостью 150 мА·ч).

Потребление электроэнергии становится важным аспектом, когда плата Arduino должна работать длительное время, питаясь от аккумулятора, как в системах удаленного мониторинга или управления, когда аккумуляторы или солнечные батареи остаются единственно возможным источником питания. Например, недавно на основе платы Arduino я реализовал автоматическое управление дверью в птичник, использовав небольшую солнечную панель для зарядки аккумулятора, емкости которого достаточно только для того, чтобы открыть и закрыть дверь два раза в день.

Потребление электроэнергии платами Arduino

Прежде всего определим параметры потребления электроэнергии наиболее популярными платами Arduino. В табл. 5.1 представлены результаты непосредственных измерений амперметром силы тока, потребляемого платами. Имейте в виду, что измерение силы потребляемого тока не самая простая задача, так как он меняется, когда при выполнении периодических задач в работу включаются таймеры и другие компоненты микроконтроллера и платы Arduino.

Таблица 5.1. Потребление электроэнергии платами Arduino

Плата Ток, мА
Uno (5 В, USB) 47
Uno (9 В, внешний источник питания) 48
Uno (5 В, с извлеченным процессором) 32
Uno (9 В, с извлеченным процессором) 40
Leonardo (5 В, USB) 42
Due (5 В, USB) 160
Due (9 В, внешний источник питания) 70
Mini Pro (9 В, внешний источник питания) 42
Mini Pro (5 В, USB) 22
Mini Pro (3,3 В, непосредственно) 8

Обратите внимание на то, как различается ток, потребляемый платами Arduino, питающимися напряжением 5 В, с процессором и без него. Разница составляет всего 15 мА, откуда получается, что остальные 32 мА потребляет сама плата. И действительно, на плате Arduino имеются интерфейс USB, светодиод On и стабилизатор напряжения 3,3 В, которые также потребляют некоторую мощность даже без микроконтроллера. Обратите также внимание на то, насколько меньше потребляет микроконтроллер, питающийся напряжением 3,3 В.

Приемы, описываемые далее, помогают снизить потребление электроэнергии процессором, но не самой платой. В примерах, приведенных в дальнейшем, я использовал плату Arduino Mini Pro, питающуюся непосредственно напряжением 3,3 В через контакты VCC и GND (рис. 5.1) в обход стабилизатора напряжения, чтобы кроме светодиода On питание подводилось только к микроконтроллеру.


Рис. 5.1. Плата Arduino Mini Pro, запитанная непосредственно напряжением 3 В

Такая схема часто используется в системах с автономным питанием от аккумуляторов, например от единственного литий-полимерного (Lithium Polymer, LiPo) аккумулятора, дающего напряжение 2,7 В, когда почти разряжен, и 4,2 В, когда полностью заряжен, который прекрасно подходит для непосредственного питания микроконтроллера ATmega328.

Ток и аккумуляторы

Эта книга посвящена программному обеспечению, поэтому я не буду останавливаться на обсуждении аккумуляторов дольше, чем необходимо. На рис. 5.2 изображены аккумуляторы, которые можно использовать для питания плат Arduino.

Слева вверху изображен цилиндрический литий-полимерный аккумулятор емкостью 2400 мА·ч. Ниже — небольшой плоский литий-полимерный аккумулятор емкостью 850 мА·ч. Литий-полимерные аккумуляторы имеют небольшой вес, могут перезаряжаться много раз и имеют большую емкость для своих веса и размеров. Справа вверху изображен 9-вольтовый никель-металлгидридный аккумулятор емкостью 200 мА·ч. Этот


Рис. 5.2. Аккумуляторы для питания плат Arduino

аккумулятор тоже поддерживает многократную перезарядку, но создан по устаревшей технологии. Так как он имеет выходное напряжение 9 В, его можно использовать для питания плат Arduino только через встроенный стабилизатор напряжения. Вы можете приобрести специальные зажимы для подключения аккумулятора к контактам питания Arduino. Наконец, справа внизу изображена 3-вольтовая незаряжаемая литиевая батарея (CR2025) емкостью около 160 мА·ч.

Как правило, чтобы получить время в часах, в течение которого аккумулятор продержится, прежде чем полностью разрядится, достаточно разделить емкость аккумулятора в миллиампер-часах [мА·ч] на силу потребляемого тока в миллиамперах [мА]:

Время работы батареи = Емкость батареи/Потребляемый ток.

Например, если для питания 3-вольтовой платы Mini Pro использовать батарею CR2025, можно ожидать, что ее хватит на 20 часов (160 мА·ч/8 мА). Если ту же плату запитать от литий-полимерного аккумулятора емкостью 2400 мА·ч, можно надеяться, что его хватит на 300 часов (2400 мА·ч /8 мА).

Снижение рабочей частоты

Большинство плат семейства Arduino работает с тактовой частотой 16 МГц. Основное потребление электроэнергии микроконтроллером происходит в моменты, когда тактовый сигнал переключается из состояния HIGH в состояние LOW, то есть частота, на которой работает процессор, оказывает существенное влияние на потребляемый ток. Конечно, уменьшение тактовой частоты приведет к снижению быстродействия микроконтроллера, что, впрочем, может не являться проблемой.

Снизить рабочую частоту микроконтроллера ATmega328 можно прямо из скетча. Для этой цели удобно использовать библиотеку Arduino Prescaler (http://playground.arduino.cc/Code/Prescaler).

Библиотека Prescaler не только позволяет уменьшить рабочую частоту микроконтроллера, но и предоставляет свои версии функций millis и delay с именами trueMillis и trueDelay. Такая замена совершенно необходима, потому что уменьшение тактовой частоты увеличивает задержки в той же пропорции.

Скетч в следующем примере включает светодиод L на 1 с и затем выключает на 5 с, в течение которых потребляемый ток измерялся для всех возможных значений деления частоты, поддерживаемых библиотекой Prescaler.

// sketch_05_01_prescale

#include <Prescaler.h>

void setup()

{

  pinMode(13, OUTPUT);

  setClockPrescaler(CLOCK_PRESCALER_256);

}

void loop()

{

  digitalWrite(13, HIGH);

  trueDelay(1000);

  digitalWrite(13, LOW);

  trueDelay(5000);

}

Библиотека предоставляет множество констант деления тактовой частоты. Так, константа CLOCK_PRESCALER_1 оставляет исходную тактовую частоту 16 МГц, а противоположная ей константа CLOCK_PRESCALER_256 делит исходную тактовую частоту на 256, устанавливая ее на уровне всего 62,5 кГц.

В табл. 5.2 показаны результаты измерения потребляемого тока на всех возможных частотах, а на рис. 5.3 те же данные представлены в виде графика. Как видно на графике, кривая потребления тока быстро выравнивается, поэтому частота 1 МГц выглядит наиболее оптимальным компромиссом между частотой и потребляемым током.

Таблица 5.2. Потребляемый ток в зависимости от тактовой частоты

Константа Эквивалентная тактовая частота Ток (светодиод выключен), мА
CLOCK_PRESCALER_1 16 МГц 7,8
CLOCK_PRESCALER_2 8 МГц 5,4
CLOCK_PRESCALER_4 4 МГц 4,0
CLOCK_PRESCALER_8 2 МГц 3,2
CLOCK_PRESCALER_16 1 МГц 2,6
CLOCK_PRESCALER_32 500 кГц 2,3
CLOCK_PRESCALER_64 250 кГц 2,2
CLOCK_PRESCALER_128 125 кГц 2,1
CLOCK_PRESCALER_256 62,5 кГц 2,1


Рис. 5.3. График зависимости потребляемого тока от тактовой частоты

Помимо необходимости использовать новые версии millis и delay снижение тактовой частоты влечет за собой еще ряд следствий. Фактически любая операция, чувствительная к изменению тактовой частоты, такая как вывод аналоговых сигналов PWM или управление сервоприводами, будет выполняться не так, как ожидается.

Большая доля тока из 2,1 мА, потребляемого на самой низкой скорости, вероятнее всего, будет поглощена светодиодом On, поэтому, если вас действительно заботит проблема снижения энергопотребления, вам стоит аккуратно выпаять его из платы.

Выключение электронных компонентов на плате

Контроллеры ATmega имеют широкие возможности управления электропитанием, настолько широкие, что способны отключать неиспользуемые электронные компоненты на плате, чтобы уменьшить потребляемый ток.

Более того, компоненты можно включать и выключать прямо из скетча. То есть можно, к примеру, включать АЦП непосредственно перед вызовом analogRead и затем выключать его.

Управление электропитанием осуществляется с помощью библиотеки avr/power.h, включающей пары функций включения/выключения. Например, вызовом функции power_adc_disable можно выключить АЦП, а вызовом power_adc_enable вновь включить.

Однако экономия электроэнергии за счет отключения компонентов будет получаться не очень большой. В ходе экспериментов с платой Mini Pro, питающейся напряжением 5 В и действующей на частоте 16 МГц, я установил, что, когда все компоненты включены, она потребляет ток 16,4 мА, а когда выключены — что-то около 14,9 мА, то есть снижение составило всего на 1,5 мА. Для измерений я использовал следующий скетч:

// sketch_05_02_powering_off

#include <avr/power.h>

void setup()

{

  pinMode(13, OUTPUT);

//  power_adc_disable();

  power_spi_disable();

//  power_twi_disable();

//  power_usart0_disable();

//  power_timer0_disable();

//  power_timer1_disable();

//  power_timer2_disable();

//  power_all_disable();

}

void loop()

{

}

Доступные функции перечислены в табл. 5.3. Каждая функция имеет пару с окончанием enable вместо disable в имени.

Таблица 5.3. Функции управления электропитанием для ATmega Arduino

Функция Описание
power_adc_disable Выключает аналоговые входы
power_spi_disable Отключает интерфейс SPI
power_twi_disable Отключает интерфейс TWI (I2C)
power_usart0_disable Отключает УСАПП (UART, интерфейс последовательной связи через USB)
power_timer0_disable Отключает таймер 0 (используется функциями millis и delay)
power_timer1_disable Отключает таймер 1
power_timer2_disable Отключает таймер 2
power_all_disable Отключает все компоненты, перечисленные выше

Энергосберегающий режим

Самый действенный способ экономии электроэнергии — перевести плату Arduino в спящий режим на время, пока она не совершает полезной работы.

Narcoleptic

Питер Кнайт создал простую в использовании библиотеку с названием Narcoleptic, которую можно получить по адресу https://code.google.com/p/narcoleptic/.

Очевидно, что нет смысла переводить Arduino в энергосберегающий режим, не имея возможности вернуть ее в нормальный режим работы! Существует два способа возврата Arduino к нормальной работе. Один из них — использовать внешнее прерывание, а другой — установить таймер, который обеспечит выход в нормальный режим через определенный интервал времени. Библиотека опирается на использование таймера.

Библиотека Narcoleptic предоставляет альтернативную функцию delay, которая переводит Arduino в энергосберегающий режим на время, указанное в вызове delay. Поскольку в ходе задержки все равно ничего не происходит, этот метод действует блестяще.

Например, вернемся к старому доброму скетчу Blink. Следующий скетч включает светодиод на 1 с, затем выключает его на 10 с и повторяет эту последовательность до бесконечности:

// sketch_05_03_blink_standard

void setup()

{

  pinMode(13, OUTPUT);

}

void loop()

{

  digitalWrite(13, HIGH);

  delay(1000);

  digitalWrite(13, LOW);

  delay(10000);

}

Ниже показана версия того же скетча, использующая библиотеку Narcoleptic:

// sketch_05_04_narcoleptic_blink

#include <Narcoleptic.h>

void setup()

{

  pinMode(13, OUTPUT);

}

void loop()

{

  digitalWrite(13, HIGH);

  Narcoleptic.delay(1000);

  digitalWrite(13, LOW);

  Narcoleptic.delay(10000);

}

Единственное отличие этой версии в том, что она импортирует библиотеку Narcoleptic и использует ее версию функции delay вместо стандартной.

Запустив оба скетча на плате Mini Pro, питающейся напряжением 5 В и действующей на частоте 16 МГц, я выяснил, что для первого скетча в момент, когда светодиод выключен, потребляемый ток составил 17,2 мА. Для версии с библиотекой Narcoleptic потребляемый ток уменьшился до 3,2 мА, из которых большую часть потребляет светодиод On (около 3 мА), то есть, если его выпаять, средний потребляемый ток должен упасть ниже 1 мА.

Микроконтроллер очень быстро переходит в энергосберегающий режим, поэтому, если в вашем проекте имеется кнопка, нажатие на которую вызывает некоторые действия, нет необходимости использовать внешнее прерывание, чтобы вывести микроконтроллер из энергосберегающего режима. Можно написать код (что, возможно, проще), который будет переводить плату Arduino в энергосберегающий режим и выводить ее обратно 10 раз в секунду, проверять нажатие кнопки, сравнивая цифровой вход со значением HIGH, и затем выполнять какие-то операции вместо возврата в энергосберегающий режим. Следующий скетч демонстрирует, как это можно реализовать:

// sketch_05_05_narcoleptic_input

#include <Narcoleptic.h>

const int ledPin = 13;

const int inputPin = 2;

void setup()

{

  pinMode(ledPin, OUTPUT);

  pinMode(inputPin, INPUT_PULLUP);

}

void loop()

{

  if (digitalRead(inputPin) == LOW)

  {

    doSomething();

  }

  Narcoleptic.delay(100);

}

void doSomething()

{

  for (int i = 0; i < 20; i++)

  {

    digitalWrite(ledPin, HIGH);

    Narcoleptic.delay(200);

    digitalWrite(ledPin, LOW);

    Narcoleptic.delay(200);

  }

}

Во время выполнения этого скетча плата Mini Pro, питающаяся напряжением 5 В и действующая на частоте 16 МГц, потребляла мизерные 3,25 мА, ожидая, пока что-то произойдет. После замыкания контакта 2 на «землю» светодиод L мигнул 20 раз, но, так как для задержки между включением и выключением светодиода скетч использует все ту же версию delay из библиотеки Narcoleptic, потребляемый ток увеличился в среднем всего лишь до 4–5 мА.

Если изменить вызов delay внутри функции loop, чтобы выводить Arduino из энергосберегающего режима, скажем, 100 раз в секунду, потребляемый ток увеличится, потому что для перевода Arduino в энергосберегающий режим действительно требуется некоторое время. Однако задержка на 50 мс (20 раз в секунду) дает довольно хорошие результаты.

Вывод из энергосберегающего режима внешними прерываниями

Только что описанный подход можно с успехом использовать в разных ситуациях, однако если требуется получить более быстрый отклик на внешнее событие, можно реализовать вывод микроконтроллера из энергосберегающего режима с помощью внешнего прерывания.

Чтобы переделать предыдущий пример и использовать контакт D2 как приемник внешних прерываний, требуется приложить дополнительные усилия, но результаты получаются немного лучше, так как отпадает необходимость периодически проверять состояние контакта. Код скетча получился сложным, поэтому сначала я покажу сам код, а потом расскажу, как он работает. Если вы пропустили главу 3 о прерываниях, то вам стоит прочитать ее перед изучением примера.

// sketch_05_06_sleep_external_wake

#include <avr/sleep.h>

const int ledPin = 13;

const int inputPin = 2;

volatile boolean flag;

void setup()

{

  pinMode(ledPin, OUTPUT);

  pinMode(inputPin, INPUT_PULLUP);

  goToSleep();

}

void loop()

{

  if (flag)

  {

    doSomething();

    flag = false;

    goToSleep();

  }

}

void setFlag()

{

  flag = true;

}

void goToSleep()

{

   set_sleep_mode(SLEEP_MODE_PWR_DOWN);

   sleep_enable();

   attachInterrupt(0, setFlag, LOW); // контакт D2

   sleep_mode(); // включить энергосберегающий режим

   // Теперь микроконтроллер простаивает, пока уровень напряжения

   // на контакте прерывания не упадет до LOW, затем...

   sleep_disable();

   detachInterrupt(0);

}

void doSomething()

{

  for (int i = 0; i < 20; i++)

  {

    digitalWrite(ledPin, HIGH);

    delay(200);

    digitalWrite(ledPin, LOW);

    delay(200);

  }

}

Первое, на что следует обратить внимание, — в примере используются несколько функций из библиотеки avr/sleep.h. Подобно библиотеке avr/power.h, использовавшейся в предыдущих примерах, эта библиотека не является частью ядра Arduino — она поддерживает семейство микроконтроллеров AVR. То есть она не будет работать в модели Arduino Due, но в то же время, если вы разрабатываете проект с низким энергопотреблением на основе Arduino, модель Due должна быть последней в списке для выбора.

После выбора контактов для использования я определяю оперативную (со спецификатором volatile) переменную, чтобы подпрограмма обработки прерываний могла взаимодействовать с остальным скетчем.

Функция setup выполняет настройку контактов и вызывает goToSleep. Эта функция устанавливает вид режима энергосбережения — в данном случае SLEEP_MODE_PWR_DOWN. В этом режиме энергопотребление снижается до минимума, поэтому есть смысл использовать его.

Далее вызывается sleep_enable. Этот вызов еще не переводит микроконтроллер в режим энергосбережения. Прежде чем сделать это, нужно настроить прерывание 0 (контакт D2), чтобы плату можно было вернуть в нормальный режим функционирования.

ПРИМЕЧАНИЕ

Обратите внимание на то, что выбран тип прерывания LOW. Это единственный тип прерывания, который можно использовать в данном примере. Типы RISING, FALLING и CHANGE не будут работать.

Вызов sleep_mode() после настройки прерывания фактически переводит микроконтроллер в энергосберегающий режим. Когда позднее произойдет возврат в нормальный режим работы, будет вызвана подпрограмма обработки прерываний и скетч продолжит выполнение со следующей строки в функции goToSleep. В этой строке сразу же выполняется вызов disable_sleep, и прерывание отключается, поэтому подпрограмма обработки прерываний не будет вызвана снова, пока скетч вновь не переведет микроконтроллер в энергосберегающий режим.

Когда падение напряжения на контакте D2 вызовет прерывание, подпрограмма-обработчик (setFlag) просто установит флаг, который проверяется функцией loop. Не забывайте, что в подпрограммах обработки прерываний нельзя использовать функцию delay и подобные ей. Поэтому функция loop должна проверить флаг и, если он установлен, вызвать ту же функцию doSomething, которая использовалась в примере с библиотекой Narcoleptic. После выполнения операции флаг сбрасывается, и Arduino вновь переводится в энергосберегающий режим.

По величине потребляемого тока этот скетч практически совпадает с примером на основе библиотеки Narcoleptic, с той лишь разницей, что во время, когда светодиод мигает, уровень потребляемого тока в данном примере выше из-за того, что используется обычная функция delay.

Использование цифровых выходов для управления питанием

Хотя в этой главе обсуждается проблема снижения энергопотребления программным способом, здесь нелишне будет дать полезный совет по уменьшению энергопотребления аппаратным способом.

На рис. 5.4 изображена схема датчика освещенности на основе фоторезистора (изменяет сопротивление в зависимости от освещенности) и постоянного сопротивления, подключенных к аналоговому входу Arduino, посредством которого измеряется степень освещенности.

Проблема данной реализации в том, что через постоянное сопротивление и фоторезистор течет постоянный ток напряжением 5 В. Если при полной освещенности она имеет сопротивление 500 Ом, то согласно закону


Рис. 5.4. Измерение освещенности с применением фоторезистора

Ома протекающий ток будет иметь значение I = V/R = 5 В/(1000 Ом + + 500 Ом) = 3,3 мА.

Вместо источника постоянного напряжения 5 В на плате Arduino можно использовать цифровой выход (рис. 5.5) и подавать на него уровень напряжения HIGH только в момент чтения значения с аналогового входа, а затем устанавливать на нем уровень LOW. В этом случае ток 3,3 мА будет протекать только в течение очень короткого промежутка времени, когда выполняется чтение, благодаря чему можно снизить общий уровень энергопотребления.


Рис. 5.5. Экономичная схема измерения освещенности

Это решение иллюстрирует следующий скетч:

// sketch_05_07_light_sensing

const int inputPin = A0;

const int powerPin = 12;

void setup()

{

  pinMode(powerPin, OUTPUT);

  Serial.begin(9600);

}

void loop()

{

  Serial.println(takeReading());

  delay(500);

}

int takeReading()

{

  digitalWrite(powerPin, HIGH);

  delay(10); // фоторезистору требуется некоторое время

  int reading = analogRead(inputPin);

  digitalWrite(powerPin, LOW);

  return reading;

}

Этот подход можно использовать не только при измерении освещенности. Можно, например, с помощью цифрового выхода управлять полевым транзистором, включающим и выключающим мощные потребители электроэнергии в вашем проекте.

В заключение

Лучшие способы уменьшить потребление электроэнергии:

• переводить микроконтроллер в режим энергосбережения, когда не требуется выполнять никаких действий;

• использовать для питания Arduino пониженное напряжение;

• уменьшать тактовую частоту Arduino.

Оглавление книги


Генерация: 0.573. Запросов К БД/Cache: 3 / 0
поделиться
Вверх Вниз