Книга: Программируем Arduino. Профессиональная работа со скетчами.

11. Программирование интерфейса USB

11. Программирование интерфейса USB

В этой главе рассматриваются разные аспекты использования порта USB на плате Arduino. В том числе возможность эмуляции клавиатуры и мыши, поддерживаемой платой Arduino Leonardo, а также подключения клавиатуры или мыши к соответственно оборудованной плате Arduino.

Эмуляция клавиатуры и мыши

Три модели Arduino — Due, Leonardo и Micro (основанная на модели Leonardo) — позволяют использовать их порт USB для эмуляции клавиатуры или мыши. Существуют также Arduino-совместимые платы, такие как LeoStick от компании Freetronics (рис. 11.1), поддерживающие аналогичную возможность.

Эта возможность широко используется, например, с музыкальными контроллерами, что позволяет плате Arduino взаимодействовать с музыкальными синтезаторами и управляющими программами, такими как Ableton Live. Благодаря ей можно, к примеру, на основе Arduino создавать новые музыкальные инструменты, управляющие музыкальным программным обеспечением с помощью датчиков поворота, прерываемых лучей света или педальной клавиатуры. К несерьезным применениям этой возможности можно отнести устройства, которые создают впечатление, что мышь живет своей жизнью независимо от действий пользователя или клавиатура сама печатает случайные символы.


Рис. 11.1. Плата LeoStick

Модель Arduino Due имеет два порта USB. Эмуляция клавиатуры и мыши осуществляется через локальный порт USB, а программирование Arduino Due — через порт USB для программирования (рис. 11.2).


Рис. 11.2. Плата Arduino Due с двумя портами USB

Эмуляция клавиатуры

Функции эмуляции клавиатуры просты в использовании. Они входят в состав стандартной библиотеки языка, поэтому для доступа к ним не требуется подключать дополнительные библиотеки. Чтобы включить режим эмуляции клавиатуры, добавьте в функцию setup следующую команду:

Keyboard.begin();

Чтобы заставить Arduino печатать что-нибудь, можно воспользоваться командами print и println, и переданный им текст появится в позиции текстового курсора:

Keyboard.println("It was the best of times.");

Чтобы сымитировать нажатие клавиш-модификаторов, например ввести комбинацию CTRL+C, используйте команду press:

Keyboard.press(KEY_LEFT_CTRL);

Keyboard.press('x');

delay(100);

Keyboard.releasrAll();

Команда press имеет односимвольный параметр, в котором ей можно передавать любые обычные символы или предопределенные константы, такие как KEY_LEFT_CTRL. После вызова команды press плата будет имитировать удержание клавиши в нажатом состоянии, пока не будет вызвана команда releaseAll. Полный список специальных клавиш можно найти по адресу http://arduino.cc/en/Reference/KeyboardModifiers.

ПРИМЕЧАНИЕ

При использовании функций эмуляции клавиатуры и мыши можно столкнуться со сложностями при программировании платы, так как она будет пытаться вводить текст, пока вы пытаетесь запрограммировать ее. Чтобы преодолеть эту проблему, примените следующий трюк: нажмите и удерживайте нажатой кнопку сброса Reset и отпустите ее, только когда в строке состояния Arduino IDE появится сообщение «uploading» («загрузка»).

Пример эмуляции клавиатуры

Следующий пример автоматически вводит текст по вашему выбору (например, пароль) после каждого сброса платы Arduino:

// sketch_11_01_keyboard

char phrase[] = "secretpassword";

void setup()

{

  Keyboard.begin();

  delay(5000);

  Keyboard.println(phrase);

}

void loop()

{

}

Этот пример можно сделать эффективнее, если активировать ввод нажатием внешней клавиши: если вы пользуетесь компьютером Mac, операционная система будет думать, что в момент сброса платы к компьютеру подключается новая клавиатура, и выведет системный диалог, который нужно успеть закрыть до того, как плата напечатает текст.

Эмуляция мыши

Эмуляция мыши реализуется с применением того же шаблона, что и эмуляция клавиатуры. Вообще говоря, нет никаких причин, препятствующих эмуляции обоих устройств ввода в одном скетче.

Чтобы запустить эмуляцию, прежде всего следует выполнить команду

Mouse.begin();

Управление указателем мыши осуществляется командой Mouse.move. Она имеет три параметра: смещение по осям x и y и поворот колесика. Все три параметра измеряются в пикселах. Эти значения могут быть положительными (смещение указателя вправо или вниз) или отрицательными (смещение указателя влево или вверх). Смещения откладываются относительно текущей позиции указателя, а так как нет никакой возможности указать абсолютные координаты указателя, эта команда лишь имитирует поведение мыши, перемещающей указатель, но не управляет самим указателем.

Сымитировать щелчок мышью можно с помощью команды click. Без параметров эта команда имитирует щелчок левой кнопкой мыши. При желании ей можно передать аргумент MOUSE_RIGHT или MOUSE_MIDDLE.

Для управления длительностью щелчка можно использовать команды Mouse.press и Mouse.release. Команда Mouse.press принимает те же необязательные аргументы, что и команда Mouse.click. Эти две команды могут пригодиться, например, чтобы заставить свою «мышь» на основе Arduino выполнять щелчок при изменении состояния цифрового входа на плате. Кроме того, с их помощью можно сымитировать двойной или даже тройной щелчок.

Пример эмуляции мыши

Следующий пример перемещает указатель мыши по экрану в случайных направлениях. Чтобы прервать программу и восстановить управление компьютером, нажмите и удерживайте кнопку сброса Reset или просто отсоедините плату от компьютера.

// sketch_11_02_mouse

void setup()

{

  Mouse.begin();

}

void loop()

}

  int x=random(61)-30;

  int y=random(61)-30;

  Mouse.move(x, y);

  delay(50);

}

Программирование хоста USB

Модели Leonardo, Due и Micro имеют возможность действовать как клавиатура или мышь, но только Due и менее известная модель Arduino Mega ADK позволяют подключать клавиатуру или мышь и использовать их в качестве устройств ввода. Эта особенность называется хостом USB (USB Host). Непосредственная поддержка этой особенности реализована только в модели Due, тем не менее существуют платы сторонних производителей, которые можно подключать к Arduino Uno или Leonardo, чтобы получить собственный хост USB.

Более того, если у вас имеется беспроводная клавиатура или мышь (за исключением моделей, подключаемых через Bluetooth), они также должны работать, если включить адаптер в разъем порта USB на плате расширения. Таким способом можно организовать беспроводное удаленное управление платой Arduino.

Хост USB позволяет подключать не только клавиатуру и мышь, но и множество других периферийных устройств USB: игровые джойстики, камеры, Bluetooth-устройства и даже телефоны на платформе Android.

Плата хоста USB и библиотека

Плата хоста USB и сопутствующие библиотеки созданы довольно давно и в настоящее время поддерживают широкий диапазон периферийных устройств. Первая плата хоста USB была разработана в Circuits@home (www.circuitsathome.com). Нынче доступны совместимые платы USB, производимые компаниями Sparkfun, SainSmart и, возможно, другими. На рис. 11.3 изображена плата Sparkfun USB Host, подключенная к Arduino Uno. Обратите внимание на то, что на момент написания данных строк эти платы были несовместимы с Arduino Leonardo, а также с другими моделями, более экзотичными, чем Uno. Поэтому перед приобретением убедитесь в совместимости плат.


Рис. 11.3. Плата Sparkfun USB Host

Данная конкретная плата имеет область, удобную для макетирования, где можно спаять дополнительные компоненты. Альтернативой платам расширения может служить плата Freetronics USBDroid (рис. 11.4). На ней имеются два порта USB: порт микроUSB для программирования и полноразмерный разъем USB для подключения клавиатуры и подобных устройств.


Рис. 11.4. Плата Freetronics USBDroid

При работе с USBDroid или неофициальными моделями плат хостов USB следует использовать оригинальную библиотеку USB_Host_Shield от Circuits@Home. При работе с официальной платой следует использовать библиотеку USB_Host_Shield_2, поддерживающую более широкий спектр устройств.

Программирование интерфейса USB с применением упомянутых библиотек — не самая простая задача. Библиотеки предоставляют крайне низкоуровневый доступ к шине USB. На веб-сайте автора (www.simonmonk.org) можно найти пример скетча sketch_11_03_host_keyboard, реализующего подключение клавиатуры с использованием платы хоста USB.

Этот скетч является адаптацией одного из примеров, сопровождающих библиотеку USB_Host_Shield. В нем, в отличие от оригинала, информация о нажатых клавишах выводится в монитор последовательного порта вместо жидкокристаллического дисплея.

Этот скетч (и пример, на котором он основан) может служить отличным шаблоном для создания собственных скетчей, так как оба они корректно обрабатывают нажатия всех клавиш. Если вас интересуют только цифровые клавиши и клавиши управления курсором, вы можете существенно упростить свой скетч.

Скетч слишком длинный, чтобы привести его здесь целиком, поэтому я покажу только наиболее важные фрагменты. Возможно, вам будет полезно загрузить этот скетч и заглядывать в него, читая описание в книге.

Скетч импортирует три библиотеки:

#include <Spi.h>

#include <Max3421e.h>

#include <Usb.h>

Библиотека Spi.h необходима для взаимодействий с контроллером хоста USB. В роли контроллера используется микросхема Max3421e, поэтому следует импортировать одноименную библиотеку. И наконец, нужно подключить еще одну библиотеку (Usb.h), основанную на библиотеке Max3421e.h, которая скрывает некоторые сложности выполнения операций с контроллером.

За командами импортирования библиотек следуют определения констант, например:

#define BANG        (0x1E)

Это просто еще один способ определения констант в C. Данную константу можно было бы определить иначе:

cons tint BANG = 0x1E;

Далее создаются объекты типов MAX3421E и USB, и в функции setup вызывается функция powerOn объекта Max:

MAX3421E Max;

USB Usb;

В функции loop вызываются функции Task обоих объектов, Max и Usb. Они проверяют готовность интерфейса USB.

void loop() {

    Max.Task();

    Usb.Task();

    if( Usb.getUsbTaskState() == USB_STATE_CONFIGURING ) {  // ждать завершения настройки

        kbd_init();

        Usb.setUsbTaskState( USB_STATE_RUNNING );

    }

    if( Usb.getUsbTaskState() == USB_STATE_RUNNING ) {  // опросить клавиатуру

        kbd_poll();

    }

}

При первом запуске интерфейс USB переходит в состояние настройки USB_STATE_CONFIGURING, в котором находится, пока с помощью kbd_init не будет установлено соединение с клавиатурой. Эта функция использует структуру записи конечной точки (ep_record), куда помещаются части сообщения, необходимого для установки соединения с клавиатурой:

ep_record[ 0 ] = *( Usb.getDevTableEntry( 0,0 ));

ep_record[ 1 ].MaxPktSize = EP_MAXPKTSIZE;

ep_record[ 1 ].Interval  = EP_POLL;

ep_record[ 1 ].sndToggle = bmSNDTOG0;

ep_record[ 1 ].rcvToggle = bmRCVTOG0;

Usb.setDevTableEntry( 1, ep_record );

/* Настроить устройство */

rcode = Usb.setConf( KBD_ADDR, 0, 1 );

После инициализации, вероятнее всего, клавиатура перейдет в состояние нормального функционирования (USB_STATE_RUNNING), обнаружив которое скетч вызовет kbd_poll для проверки нажатия клавиши на клавиатуре.

Ключевая строка в kbd_poll

rcode = Usb.inTransfer( KBD_ADDR, KBD_EP, 8, buf );

читает скан-код клавиши, чтобы определить, была ли нажата какая-нибудь клавиша. Этот код не является кодом ASCII. Преобразование скан-кодов в коды ASCII осуществляется в функции HIDtoA. Эта функция — самая сложная в скетче, но вы можете просто копировать ее в свои скетчи, не вдаваясь в детали ее работы. Список скан-кодов и порядок их преобразования в коды ASCII можно найти по адресу www.win.tue.nl/~aeb/linux/kbd/scancodes-1.html.

Одной из интересных особенностей протокола USB-устройств для взаимодействия с человеком (Human Interface Device, HID), используемого для работы с клавиатурой, является возможность управления светодиодными индикаторами Scroll Lock, Caps Lock и Num Lock. Функция kbd_poll включает и выключает эти индикаторы в ответ на нажатия клавиш Scroll Lock, Caps Lock и Num Lock, однако вы можете написать коротенький скетч, например sketch_11_04_host_scroll_lock, который просто мигает светодиодными индикаторами на клавиатуре.

Ключевая функция в этом скетче:

void toggleLEDs( void )

{

  if (leds == 0) {

    leds = 0b00000111;

  }

  else {

    leds = 0;

  }

  Usb.setReport( KBD_ADDR, 0, 1, KBD_IF, 0x02, 0, &leds );

}

Три младших бита в байте — это три флага, управляющих состояниями индикаторов на клавиатуре.

Хост USB на плате Arduino Due

Плата Arduino Due способна действовать как встроенный хост USB. На момент написания этих строк данная возможность рассматривалась командой разработчиков Arduino как экспериментальная. Загляните в официальную документацию Arduino (http://arduino.cc/en/Reference/USBHost), чтобы определить текущее состояние дел в этой области и выяснить, произошли ли изменения в способе ее использования.

Модель Due не имеет полноразмерного разъема USB, к которому можно было бы подключить клавиатуру или мышь. Для подключения таких устройств требуется использовать кабель Micro USB OTG Host Cable (рис. 11.5). На этом снимке к плате Arduino Due подключен адаптер беспроводной клавиатуры, но точно так же можно подключить обычную клавиатуру USB.

Библиотеки поддержки USB в Arduino Due имеют более простой интерфейс, чем библиотека обслуживания хоста USB, и вместо скан-кодов


Рис. 11.5. Arduino Due с подключенным кабелем Micro USB OTG Host Cable и клавиатурой

возвращают коды ASCII нажатых клавиш. Следующий пример демонстрирует взаимодействие с клавиатурой. Он просто выводит в монитор последовательного порта символы, соответствующие нажатым клавишам:

// sketch_11_05_keyboard_due

#include <KeyboardController.h>

USBHost usb;

KeyboardController keyboard(usb);

void setup()

{

  Serial.begin(9600);

  Serial.println("Program started");

  delay(200);

}

void loop()

{

  usb.Task();

}

// Эта функция обрабатывает нажатия клавиш

void keyPressed()

{

  char key = keyboard.getKey();

  Serial.write(key);

}

Библиотека KeyboardController вызывает функцию keyPressed в скетче каждый раз, когда происходит нажатие какой-либо клавиши. Аналогично можно перехватывать отпускания клавиш с помощью функции keyReleased. Чтобы определить нажатую клавишу, необходимо вызвать следующие функции объекта keyboard:

• getModifiers — возвращает битовую маску с информацией об удерживаемых нажатыми клавишах-модификаторах (Shift, Ctrl и т.д.). Коды клавиш модификаторов можно найти по адресу http://arduino.cc/en/Reference/GetModifiers;

• getKey — возвращает код ASCII текущей нажатой клавиши;

• getOemKey — возвращает скан-код клавиши.

Взаимодействие с мышью осуществляется так же просто и с применением похожего шаблона. Следующий пример выводит буквы L, R, U или D в зависимости от направления перемещения указателя мыши — влево, вправо, вверх или вниз:

// sketch_11_06_mouse_due

#include <MouseController.h>

USBHost usb;

MouseController mouse(usb);

void setup()

{

  Serial.begin(9600);

  Serial.println("Program started");

  delay(200);

}

void loop()

{

  usb.Task();

}

// Эта функция обрабатывает перемещения мыши

void mouseMoved()

{

  int x = mouse.getXChange();

  int y = mouse.getYChange();

  if (x > 50) Serial.print("R");

  if (x < -50) Serial.print("L");

  if (y > 50) Serial.print("D");

  if (y < -50) Serial.print("U");

}

Помимо mouseMoved в скетч можно добавить следующие функции для обработки других событий от мыши:

• mouseDragged — это событие генерируется, когда происходит перемещение мыши с нажатой левой кнопкой;

• mousePressed — это событие генерируется, когда происходит нажатие кнопки мыши, и должно сопровождаться вызовом mouse.getButton с аргументом LEFT_BUTTON, RIGHT_BUTTON или MIDDLE_BUTTON для определения нажатой кнопки — возвращает true, если была нажата кнопка, соответствующая аргументу;

• mouseReleased — это событие является парным для mousePressed и генерируется, когда происходит отпускание кнопки.

В заключение

В этой главе мы познакомились с несколькими способами использования Arduino с устройствами USB.

В следующей главе посмотрим, как подключать Arduino к проводным и беспроводным сетям, познакомимся с некоторыми приемами программирования сетевых взаимодействий, а также попробуем использовать платы расширения Ethernet и WiFi.

Оглавление книги


Генерация: 0.471. Запросов К БД/Cache: 3 / 1
поделиться
Вверх Вниз