Книга: Программируем Arduino. Профессиональная работа со скетчами.

10. Программирование последовательного интерфейса

10. Программирование последовательного интерфейса

Последовательный интерфейс вам должен быть хорошо знаком. Он используется для программирования платы Arduino, а также для взаимодействий с монитором последовательного порта, посредством которого можно организовать обмен данными между платой и компьютером. Это можно делать через адаптер, связывающий порт USB с последовательным портом на плате Arduino, или непосредственно через адаптер последовательного порта. Адаптер последовательного порта часто называют последовательным портом ТТЛ или просто последовательным портом. Аббревиатура ТТЛ означает «транзистор-транзисторная логика» — это редко используемая в настоящее время технология, основанная на 5-вольтовой логике.

Последовательный интерфейс этого вида не является шиной. Он поддерживает взаимодействия вида «точка–точка», в которые вовлечены только два устройства — обычно сама плата Arduino и периферийное устройство.

Последовательный интерфейс ТТЛ вместо I2C или SPI обычно поддерживают большие периферийные устройства или устройства, разработанные довольно давно и традиционно использующие последовательный интерфейс ТТЛ. К их числу относятся также устройства, изначально предназначенные для подключения к последовательному порту персонального компьютера. Примерами могут служить модули GPS, мультиметры с возможностью передачи данных, а также устройства чтения штрихкодов и радиометок.

Аппаратная часть последовательного интерфейса

На рис. 10.1 изображена схема последовательного интерфейса на плате Arduino Uno.


Рис. 10.1. Последовательный интерфейс на плате Arduino Uno

Микроконтроллер ATmega328 на плате Arduino Uno имеет два контакта: Rx и Tx (прием и передача соответственно). Они дополнительно выводятся на контакты D0 и D1, но, если вы решите использовать их как обычные входы/выходы, имейте в виду, что не сможете запрограммировать Arduino, пока к ним подключены внешние устройства.

Контакты Rx и Tx составляют последовательный интерфейс аппаратного универсального асинхронного приемопередатчика (УАПП) (Universal Asynchronous Receiver Transmitter, UART) в ATmega328. Этот компонент микроконтроллера отвечает за передачу байтов данных в микроконтроллер и их прием из него.

Модель Uno имеет отдельный процессор, действующий как адаптер между портом USB и последовательным портом. Помимо различий в уровнях сигналов, шина USB имеет также более сложный протокол, чем последовательный порт, поэтому за кулисами выполняется масса преобразований разного рода, чтобы создавалось ощущение, что последовательный порт микроконтроллера ATmega328 взаимодействует с компьютером напрямую.

Модель Arduino Leonardo не имеет отдельной микросхемы интерфейса USB, вместо этого в ней используется микроконтроллер ATmega, включающий два кристалла УАПП и один интерфейс USB (рис. 10.2).


Рис. 10.2. Аппаратная поддержка последовательного интерфейса на плате Arduino Leonardo

Один из приемопередатчиков УАПП обслуживает интерфейс USB, а другой соединен с контактами Rx и Tx (D0 и D1). Это позволяет подключать внешние устройства к контактам Tx и Rx и сохранить возможность программирования платы Arduino и обмена данными с монитором последовательного порта.

Другие модели Arduino имеют иное количество и схему подключения последовательных портов, как показано в табл. 10.1. Обратите внимание на то, что Due является единственной моделью Arduino, в которой последовательные порты работают с уровнями сигналов 3,3 В, а не 5 В.

Последовательный интерфейс ТТЛ способен поддерживать связь лишь по относительно коротким линиям (в пределах нескольких метров), и чем выше скорость обмена, тем короче должна быть линия. Для передачи данных на большие расстояния был разработан электрический стандарт RS232. Персональные компьютеры, выпускавшиеся до недавнего прошлого, часто снабжались последовательными портами RS232. Стандарт RS232 изменил уровни сигналов, чтобы обеспечить передачу данных на большие расстояния, чем позволяет последовательный интерфейс ТТЛ.

Таблица 10.1. Последовательные интерфейсы УАПП в разных моделях Arduino

Модель Число последовательных портов Подробности
Uno 1 Линия Rx подключена к контакту D0, а линия Tx — к контакту D1. Этот порт используется также интерфейсом USB
Leonardo 2 Отдельный порт для интерфейса USB. Линия Rx подключена к контакту D0, а линия Tx — к контакту D1
Mega2560 4 Интерфейс USB подключен к контактам D0 и D1. Три других порта: Serial1 — к контактам 19 (Rx) и 18 (Tx), Serial2 — к контактам 17 (Rx) и 16 (Tx), Serial3 — к контактам 15 (Rx) и 14 (Tx)
Due 4 Отдельный порт для интерфейса USB. Последовательный порт 0 использует контакты D0 (Rx) и D1 (Tx). Три других порта: Serial1 — к контактам 19 (Rx) и 18 (Tx), Serial2 — к контактам 17 (Rx) и 16 (Tx), Serial3 — к контактам 15 (Rx) и 14 (Tx)

Протокол последовательного интерфейса

Протокол последовательного интерфейса и большая часть терминологии появились еще на заре развития компьютерных сетей. Отправитель и получатель должны были договориться о скорости обмена данными. Эта скорость, измеряемая в бодах, устанавливалась на обоих концах соединения перед началом обмена. Скорость в бодах определяет частоту переходов между уровнями сигнала. Она совпадала бы с количеством бит в секунду, если бы байт данных имел стартовый бит, стоповый бит и бит четности. То есть, чтобы получить грубую оценку скорости передачи в байтах в секунду, нужно скорость в бодах разделить на 10.

Скорость в бодах выбиралась из числа предопределенных стандартом значений. Увидеть эти значения можно в раскрывающемся списке в окне монитора последовательного порта. Программное обеспечение Arduino поддерживает следующие скорости: 300, 1200, 4800, 9600, 14 400, 19 200, 28 800, 38 400, 57 600 и 115 200 бод.

Чаще всего для связи с Arduino используется скорость 9600 бод, которая выбирается по умолчанию. Этот выбор не обусловлен какими-то серьезными причинами, так как связь с платами Arduino действует вполне надежно даже на скорости 115 200 бод. Эту скорость можно использовать в проектах, где требуется высокая скорость передачи. Также часто используется скорость 2400 бод. Некоторые периферийные устройства, такие как адаптеры Bluetooth и аппаратура GPS, работают на этой скорости.

Другой довольно запутанный параметр настройки последовательного интерфейса, который может вам встретиться, — это строка вида 8N1. В данном случае она означает: размер пакета 8 бит, отсутствие контроля четности и 1 стоповый бит. Несмотря на возможность других комбинаций, практически все устройства, которые вам попадутся, будут использовать параметр 8N1.

Команды последовательного порта

Команды последовательного порта включены в стандартную библиотеку Arduino, поэтому нет необходимости использовать в скетчах команду include.

Запуск взаимодействий по последовательному порту осуществляется командой Serial.begin, которая принимает параметр со скоростью в бодах:

Serial.begin(9600);

Обычно она вызывается только один раз, в функции setup.

Если используется плата, имеющая несколько последовательных портов, и вы собираетесь организовать обмен через порт по умолчанию (порт 0), достаточно вызвать простую команду Serial.begin. Но для других портов нужно указать в команде номер порта после слова Serial. Например, чтобы запустить взаимодействия по последовательному порту 3 на плате Arduino Due, скетч должен выполнить следующую команду:

Serial3.begin(9600);

После вызова команды Serial.begin приемопередатчик УАПП переходит в режим приема входящих данных и автоматически сохраняет их в буфере, поэтому, даже если процессор занят в это время чем-то другим, данные не будут теряться, пока буфер не переполнится.

Функция loop может проверить наличие входящих данных с помощью функции Serial.available. Она возвращает число байтов, доступных для чтения. Если в буфере нет ни одного байта, она вернет 0. В языке C это равносильно значению false, поэтому часто можно видеть такой код, проверяющий доступность данных:

void loop()

{

  if (Serial.available())

  {

    // прочитать и обработать следующий байт

  }

}

Команда read не имеет параметров и просто читает следующий доступный байт из буфера. Функция readBytes читает доступные байты в буфер, организованный внутри скетча. Она принимает два аргумента: буфер (это должна быть ссылка на массив байтов) и максимальное число байтов для чтения. Эта команда может пригодиться в проектах для пересылки в плату Arduino строк переменной длины. Но вообще лучше избегать этого и стараться осуществлять обмен максимально простыми данными фиксированного размера.

Также могут пригодиться функции parseInt и parseFloat, позволяющие сохранять строки, пересылаемые в плату Arduino, как числа в переменных типа int и float соответственно.

void loop()

{

  if (Serial.available())

  {

    int x = parseInt();

  }

}

Обе функции читают символы, пока не достигнут конца строки или не встретят пробел или другой нецифровой символ, и затем преобразуют прочитанную последовательность цифр в числовое значение.

Перед использованием функций, таких как parseInt и parseFloat, убедитесь, что понимаете, зачем вы это делаете. Мне приходилось видеть код, написанный другими, который преобразовывал значение int в массив символов и посылал его второй плате Arduino, которая преобразовывала массив обратно в значение int. Такое решение нельзя назвать удачным по следующим причинам.

• В этом нет необходимости. Двоичные данные передаются через последовательный интерфейс ничуть не хуже. Достаточно просто передать старший и младший байты значения int и затем собрать их обратно в значение int на стороне получателя.

• Преобразование чисел в строки и обратно выполняется медленно.

• Вместо шести символов (включая завершающий нулевой символ) по линии связи можно передать всего два байта, составляющие значение int.

Если устройство, с которым вы взаимодействуете, вам неподконтрольно и протоколом предполагается передача чисел в виде строк или полей данных переменной длины, то применение этих функций вполне оправданно. Но, если реализация протокола полностью находится в ваших руках, облегчите себе жизнь и откажитесь от ненужных сложностей, связанных с преобразованием типов и передачей сообщений в разных форматах.

Примеры, приведенные в разделе «Примеры использования последовательного интерфейса» далее в этой главе, можно использовать в качестве шаблонов при разработке своего кода, осуществляющего обмен данными.

Поддержка последовательного интерфейса включает массу функций, многие из которых вам никогда не понадобятся. Мы охватили здесь только самые необходимые. Информацию об остальных ищите в документации с описанием последовательного интерфейса Arduino по адресу http://arduino.cc/en/Reference/Serial [8].

Библиотека SoftwareSerial

Иногда, особенно при использовании модели Arduino Uno, единственного последовательного порта оказывается недостаточно. Библиотека SoftwareSerial позволяет использовать для последовательных взаимодействий практически любую пару контактов, хотя и с некоторыми ограничениями.

• С помощью SoftwareSerial невозможно принимать данные одновременно по нескольким портам.

• Если скетч использует таймеры или внешние прерывания, могут возникать проблемы.

Функции в библиотеке имеют те же имена, что и команды Serial, но продуманы лучше. Библиотека SoftwareSerial поддерживает последовательные взаимодействия с устройствами, использующими инвертированные сигналы, такими как дальномеры MaxSonar. Кроме того, создание объектов SoftwareSerial для соединений выполняется более ясным способом, чем стандартный подход с использованием номеров после слова Serial.

В табл. 10.2 перечислены контакты на платах Uno и Leonardo, которые может использовать библиотека SoftwareSerial. Если вы работаете с платой, имеющей четыре аппаратных последовательных порта, библиотека SoftwareSerial едва ли вам понадобится. Номера контактов без префикса A соответствуют цифровым входам/выходам.

Таблица 10.2. Контакты, доступные библиотеке SoftwareSerial

Модель Контакты для линии Rx Контакты для линии Tx
Uno Любые, кроме 0 и 1 Любые, кроме 0 и 1
Leonardo Любые, кроме 0 и 1 8, 9, 10, 11, 14 (MISO), 15 (SCK), 16 (MOSI)

При создании объекта SoftwareSerial нужно передать два параметра с номерами контактов для линий Rx и Tx. Чтобы запустить взаимодействия, нужно вызвать функцию begin и передать ей скорость в бодах:

#include <SoftwareSerial.h>

SoftwareSerial mySerial(10, 11); // RX, TX

void setup()

{

  mySerial.begin(9600);

  mySerial.println("Hello, world?");

}

Полное описание библиотеки SoftwareSerial можно найти по адресу http://arduino.cc/en/Reference/SoftwareSerial [9].

Примеры использования последовательного интерфейса

В этом разделе демонстрируется несколько примеров использования УАПП и библиотеки SoftwareSerial.

Передача из компьютера в Arduino через USB

В первом примере демонстрируется применение монитора последовательного порта для передачи команд в плату Arduino. Раз в секунду Arduino будет посылать значение, прочитанное с аналогового входа A0, и одновременно ждать получения односимвольных команд g (go — вперед) и s (stop — стоп), управляющих передачей прочитанных значений. На рис. 10.3 изображено окно монитора последовательного порта с данными, полученными во время работы скетча.


Рис. 10.3. Окно монитора последовательного порта с данными, полученными от платы Arduino

В данном случае из-за того, что вывод производится непосредственно в окно монитора последовательного порта, данные, прочитанные с аналогового входа, передаются не в двоичном, а в текстовом виде.

Далее приводится скетч для этого примера:

// sketch_10_01_PC_to_Arduino

const int readingPin = A0;

boolean sendReadings = true;

void setup()

{

  Serial.begin(9600);

}

void loop()

{

  if (Serial.available())

  {

    char ch = Serial.read();

    if (ch == 'g')

    {

      sendReadings = true;

    }

    else if (ch == 's')

    {

      sendReadings = false;

    }

  }

  if (sendReadings)

  {

    int reading = analogRead(readingPin);

    Serial.println(reading);

    delay(1000);

  }

}

Функция loop проверяет получение данных и, если они имеются, читает их по одному байту как символы. После полученный байт сравнивается с командами 's' и 'g', и переменной sendReadings присваивается соответствующее значение.

Затем по значению переменной sendReadings определяется необходимость чтения аналогового входа и вывода результатов. Если флаг sendReadings имеет значение true, перед отправкой следующего значения выполняется задержка на одну секунду.

Использование функции delay означает, что значение sendReadings сможет измениться только в следующей итерации функции loop. В данном скетче это не является проблемой, но в других ситуациях может потребоваться использовать другое решение, не блокирующее работу функции loop. Подробнее о подобных решениях рассказывается в главе 14.

Передача из Arduino в Arduino

Второй пример иллюстрирует передачу данных из одной платы Arduino Uno в другую. В данном случае одна плата Arduino передает значение, прочитанное с входа A1, другой плате, которая затем по этому значению определяет частоту мигания встроенного светодиода L.

На рис. 10.4 изображена схема соединения плат.


Рис. 10.4. Две платы Ardiono Uno взаимодействуют через последовательный порт

Контакт Tx на одной плате Arduino должен быть подключен к контакту Rx на другой и наоборот. В этом примере обе платы используют библиотеку SoftwareSerial, контакты 8 служат линией Rx, а контакты 9 — линией Tx.

Контакты GND обеих плат должны быть соединены. Чтобы плата-отправитель могла служить источником питания для платы-получателя, необходимо также соединить их контакты 5V. К плате-отправителю подключено переменное сопротивление, соединяющее гнезда A0 и A2. Настроив контакты A0 и A2 на работу в режиме цифровых выходов и установив на выходе A2 уровень HIGH, можно изменять уровень напряжения на контакте A1 в диапазоне от 0 до 5 В, вращая шток резистора, и тем самым управлять частотой мигания светодиода на другой плате Arduino.

Далее приводится скетч для платы-отправителя:

// sketch_10_02_Adruino_Sender

#include "SoftwareSerial.h"

const int readingPin = A1;

const int plusPin = A2;

const int gndPin = A0;

SoftwareSerial sender(8, 9); // RX, TX

void setup()

{

  pinMode(gndPin, OUTPUT);

  pinMode(plusPin, OUTPUT);

  digitalWrite(plusPin, HIGH);

  sender.begin(9600);

}

void loop()

{

  int reading = analogRead(readingPin);

  byte h = highByte(reading);

  byte l = lowByte(reading);

  sender.write(h);

  sender.write(l);

  delay(1000);

}

Перед отправкой прочитанное 16-битное значение (int) разбивается на старший и младший байты, затем оба байта посылаются в последовательный интерфейс командой write. Команды print и println преобразуют свой аргумент в строку, но команда write посылает байт в двоичном виде.

Далее приводится скетч для платы-получателя:

// sketch_10_03_Adruino_Receiver

#include "SoftwareSerial.h"

const int ledPin = 13;

int reading = 0;

SoftwareSerial receiver(8, 9); // RX, TX

void setup()

{

  pinMode(ledPin, OUTPUT);

  receiver.begin(9600);

}

void loop()

{

  if (receiver.available() > 1)

  {

    byte h = receiver.read();

    byte l = receiver.read();

    reading = (h << 8) + l;

  }

  flash(reading);

}

void flash(int rate)

{

  // 0 — редко, 1023 — очень часто

  int period = (50 + (1023 — rate) / 4);

  digitalWrite(ledPin, HIGH);

  delay(period);

  digitalWrite(ledPin, LOW);

  delay(period);

}

Принимающий скетч ждет, пока будет получено не менее 2 байт, и затем восстанавливает значение типа int, сдвигая старший байт на 8 бит влево и прибавляя к результату младший байт.

Для передачи данных с более сложной структурой можно использовать библиотеку EasyTransfer: www.billporter.info/2011/05/30/easytransfer-arduino-library/.

Несмотря на то что в этом примере контакт Tx одной платы Arduino связан проводом с контактом Rx другой, для взаимодействий точно так же можно использовать беспроводные соединения. Многие модули беспроводной связи действуют прозрачно, то есть как если бы связь осуществлялась по проводам.

Модуль GPS

В заключительном примере демонстрируется использование последовательного интерфейса ТТЛ для чтения географических координат (широты и долготы) из модуля глобальной навигационной системы (Global Positioning System, GPS), которые затем форматируются и выводятся в монитор последовательного порта (рис. 10.5).


Рис. 10.5. Чтение данных из модуля GPS в плату Arduino

Связь с модулем GPS возможна только в одну сторону, поэтому достаточно соединить вывод Tx модуля с выводом Rx на плате Arduino. В примере используется модуль GPS, выпускаемый компанией Sparkfun Venus (www.sparkfun.com/products/11058). Подобно большинству других модулей GPS, он имеет последовательный интерфейс ТТЛ и раз в секунду посылает сообщения на скорости 9600 бод.

Формат сообщений соответствует стандарту национальной ассоциации морской электроники (National Marine Electronics Association, NMEA). Сообщение — это текстовая строка, завершающаяся символом перевода строки, с полями, разделенными запятыми. Далее показано, как выглядит типичное сообщение:

$GPRMC,081019.548,A,5342.6316,N,00239.8728,W,000.0,079.7,110613,,,A*76

Поля в данном примере имеют следующие значения:

• $GPRMC — тип сообщения;

• 081019.548 — время (очень точное) в 24-часовом формате, 8:10:19.548;

• 5342.6316, N — широта, умноженная на 100, то есть 53,426316 градуса северной широты;

• 00239.8728,W — долгота, умноженная на 100, то есть 0,2398728 градуса западной долготы;

• 000.0 — скорость;

• 079.7 — курс 79,7 градуса;

• 110613 — дата, 11 июня 2013.

Остальные поля для данного примера не имеют значения.

ПРИМЕЧАНИЕ

Полный список сообщений NMEA GPS можно найти по адресу http://aprs.gids.nl/nmea/.

Далее приводится скетч для этого примера:

#include <SoftwareSerial.h>

SoftwareSerial gpsSerial(10, 11); // RX, TX (TX не используется)

const int sentenceSize = 80;

char sentence[sentenceSize];

void setup()

{

  Serial.begin(9600);

  gpsSerial.begin(9600);

}

void loop()

{

  static int i = 0;

  if (gpsSerial.available())

  {

    char ch = gpsSerial.read();

    if (ch != 'n' && i < sentenceSize)

    {

      sentence[i] = ch;

      i++;

    }

    else

    {

     sentence[i] = '';

     i = 0;

     //Serial.println(sentence);

     displayGPS();

    }

  }

}

void displayGPS()

{

  char field[20];

  getField(field, 0);

  if (strcmp(field, "$GPRMC") == 0)

  {

    Serial.print("Lat: ");

    getField(field, 3);  // число

    Serial.print(field);

    getField(field, 4); // широта N/S

    Serial.print(field);

    Serial.print(" Long: ");

    getField(field, 5);  // число

    Serial.print(field);

    getField(field, 6);  // долгота E/W

    Serial.println(field);

  }

}

void getField(char* buffer, int index)

{

  int sentencePos = 0;

  int fieldPos = 0;

  int commaCount = 0;

  while (sentencePos < sentenceSize)

  {

    if (sentence[sentencePos] == ',')

    {

      commaCount ++;

      sentencePos ++;

    }

    if (commaCount == index)

    {

      buffer[fieldPos] = sentence[sentencePos];

      fieldPos ++;

    }

    sentencePos ++;

  }

  buffer[fieldPos] = '';

}

Сообщения, посылаемые модулем GPS, имеют разную длину, но не более 80 символов, поэтому в скетче используется буфер емкостью 80 символов, который заполняется данными, пока не заполнится или не будет получен признак конца строки.

После того как полное сообщение будет прочитано, в конец буфера вставляется нулевой символ, завершающий строки в языке C. Это необходимо, только если вы пожелаете «напечатать» сообщение в его исходном виде.

Остальная часть скетча реализует извлечение полей и форматирование выходной строки для записи в монитор последовательного порта. Функция getField извлекает текст из поля с указанным индексом.

Функция displayGPS игнорирует любые сообщения, тип которых отличается от "$GPRMC", и извлекает широту и долготу, а также односимвольные названия полушарий для отображения.

В заключение

В этой главе мы исследовали несколько способов программирования взаимодействий через последовательный интерфейс между платами Arduino, периферийными устройствами и компьютерами.

В следующей главе мы обратим внимание на одну интересную особенность Arduino Leonardo, которая позволяет имитировать поведение периферийных устройств USB, таких как клавиатура и мышь. А также рассмотрим некоторые аспекты программирования интерфейса USB.

Оглавление книги


Генерация: 0.069. Запросов К БД/Cache: 0 / 0
поделиться
Вверх Вниз